openharmony-standard: Ensure proper distro configuration

This will skip the recipe if openharmony is not enabled in DISTRO_FEATURES,
if TOOLCHAIN is not clang or if RUNTIME is not llvm.

Signed-off-by: Esben Haabendal <esben.haabendal@huawei.com>

recipes-openharmony/openharmony/openharmony-standard_3.0.bb

@@ -12,11 +12,15 @@ PD & OFL-1.1 & OpenSSL & MulanPSL-2.0 & bzip2-1.0.6 & ISC & ICU & IJG & Libpng &
 MPL-1.1 & MPL-2.0 & FTL"
 LIC_FILES_CHKSUM = "file://build/LICENSE;md5=cfba563cea4ce607306f8a392f19bf6c"
 
+require sanity-check.inc
+
 DEPENDS += "nodejs-native"
 DEPENDS += "bison-native"
 DEPENDS += "ruby-native"
 
-require ${PN}-sources-${OPENHARMONY_VERSION}.inc
+# Note: Using include instead of require to avoid parser error skipping recipe
+include ${PN}-sources-${OPENHARMONY_VERSION}.inc
+
 require musl-ldso-paths-sanity-check.inc
 
 FILESEXTRAPATHS:prepend := "${THISDIR}/openharmony-${OPENHARMONY_VERSION}:"

recipes-openharmony/openharmony/openharmony-standard_3.1.bb

@@ -12,6 +12,8 @@ PD & OFL-1.1 & OpenSSL & MulanPSL-2.0 & bzip2-1.0.6 & ISC & ICU & IJG & Libpng &
 MPL-1.1 & MPL-2.0 & FTL"
 LIC_FILES_CHKSUM = "file://build/LICENSE;md5=cfba563cea4ce607306f8a392f19bf6c"
 
+require sanity-check.inc
+
 DEPENDS += "nodejs-native"
 DEPENDS += "bison-native"
 DEPENDS += "ruby-native"
@@ -23,7 +25,9 @@ DEPENDS += "fts"
 FILESEXTRAPATHS:prepend := "${THISDIR}/openharmony-${OPENHARMONY_VERSION}:"
 FILESEXTRAPATHS:prepend := "${THISDIR}/openharmony-standard-${OPENHARMONY_VERSION}:"
 
-require ${PN}-sources-${OPENHARMONY_VERSION}.inc
+# Note: Using include instead of require to avoid parser error skipping recipe
+include ${PN}-sources-${OPENHARMONY_VERSION}.inc
+
 require java-tools.inc
 require musl-ldso-paths-sanity-check.inc
 

recipes-openharmony/openharmony/sanity-check.inc

+# SPDX-FileCopyrightText: Huawei Inc.
+#
+# SPDX-License-Identifier: Apache-2.0
+
+# Skip recipe if openharmony is not in DISTRO_FEATURES
+inherit features_check
+REQUIRED_DISTRO_FEATURES = "openharmony"
+
+# Skip recipe if TOOLCHAIN != "clang" or RUNTIME != "llvm"
+python () {
+    toolchain = d.getVar('TOOLCHAIN')
+    runtime = d.getVar('RUNTIME')
+    tclibc = d.getVar('TCLIBC')
+    if toolchain != "clang":
+        raise bb.parse.SkipRecipe("TOOLCHAIN is not clang")
+    if runtime != "llvm":
+        raise bb.parse.SkipRecipe("RUNTIME is not llvm")
+    if tclibc != "musl":
+        raise bb.parse.SkipRecipe("TCLIBC is not musl")
+}