exceptions.ttcn 5.03 KB
Newer Older
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
/******************************************************************************
 * Copyright (c) 2000-2021 Ericsson Telecom AB
 * All rights reserved. This program and the accompanying materials
 * are made available under the terms of the Eclipse Public License v2.0
 * which accompanies this distribution, and is available at
 * https://www.eclipse.org/org/documents/epl-2.0/EPL-2.0.html
 *
 * Contributors:
 *   Baranyi, Botond
 *
 ******************************************************************************/
module exceptions {

type record Rec {
  integer num,
  charstring str
}

type record of integer RoI;

type class BaseClass {
  public function toString() return universal charstring {
    return "BaseClass";
  }
}

type class Class extends BaseClass {
  public function toString() return universal charstring {
    return "Class";
  }
}

type class Class2 {
  public function toString() return universal charstring {
    return "Class2";
  }
}

type component CT {
  var integer cvar := 4;
  timer tmr;
}

type integer SmallNumber (-100..100);


function test_block(in integer p_exception_type, inout integer p_finally_counter) runs on CT {
  var integer v_finally_increment := 1;
  {
    select (p_exception_type) {
      case (1) {
        raise 3; // integer
      }
      case (2) {
        var integer x := 6;
        raise x;
      }
      case (3) {
        raise Rec: { 2, "xy" };
      }
      case (4) {
        raise Class.create();
      }
      case (5) {
        raise SmallNumber:11;
      }
      case (6) {
        var Rec x := { 9, "" };
        raise x.num;
      }
      case (7) {
        raise RoI[-]: 23;
      }
      case (8) {
        raise Class2.create;
      }
    }
    // otherwise don't raise anything
  }
  catch (SmallNumber a) {
    if (a != 11) {
      setverdict(fail, "Unexpected SmallNumber exception: ", a);
    }
  }
  catch (Rec.num a) {
    if (a != 9) {
      setverdict(fail, "Unexpected Rec.num exception: ", a);
    }
  }
  catch (RoI[-] a) {
    if (a != 23) {
      setverdict(fail, "Unexpected RoI[-] exception: ", a);
    }
  }
  catch (integer a) {
    var integer a2 := a;
    if (a2 != 3 and a2 != 6) {
      setverdict(fail, "Unexpected integer exception: ", a2);
    }
  }
  catch (Rec b) {
    if (b != { 2, "xy" }) {
      setverdict(fail, "Unexpected Rec exception: ", b);
    }
  }
  catch (BaseClass c) {
    if (c.toString() != "Class") {
      setverdict(fail, "Unexpected BaseClass exception: ", c);
    }
  }
  catch (Class c) {
    setverdict(fail, "Unexpected Class exception: ", c);
  }
  catch (object c) {
    if (c.toString() != "Class2") {
      setverdict(fail, "Unexpected BaseClass exception: ", c);
    }
  }
  finally {
    p_finally_counter := p_finally_counter + v_finally_increment;
    setverdict(pass);
  }
}

testcase tc_exceptions_block() runs on CT {
  var integer finally_counter := 0;
  for (var integer i := 1; i <= 8; i := i + 1) {
    test_block(i, finally_counter);
  }
  test_block(200, finally_counter);
  
  if (finally_counter != 9) {
    setverdict(fail, "Invalid 'finally' execution count: ", finally_counter);
  }
}


function test_function(boolean p_raise, inout integer p_finally_counter) runs on CT {
  if (p_raise) {
    raise "abc";
  }
}
catch (charstring x) {
  if (x != "abc") {
    setverdict(fail, "Unexpected exception: ", x);
  }
}
finally {
  p_finally_counter := p_finally_counter + 1;
  setverdict(pass);
}

testcase tc_exceptions_function() runs on CT {
  var integer finally_counter := 0;
  test_function(true, finally_counter);
  test_function(false, finally_counter);
  if (finally_counter != 2) {
    setverdict(fail, "Invalid 'finally' execution count: ", finally_counter);
  }
}


altstep test_altstep(boolean p_raise, inout integer p_finally_counter) runs on CT {
  [] tmr.timeout {
    if (p_raise) {
      raise 6;
    }
  }
}
catch (integer x) {
  if (x != 6) {
    setverdict(fail, "Unexpected exception: ", x);
  }
}
finally {
  p_finally_counter := p_finally_counter + 1;
  setverdict(pass);
}

testcase tc_exceptions_altstep() runs on CT {
  var integer finally_counter := 0;
  tmr.start(0.1);
  test_altstep(true, finally_counter);
  tmr.start(0.1);
  alt {
    [] test_altstep(false, finally_counter);
  }
  cvar := finally_counter;
  var default def := activate(test_altstep(true, cvar));
  timer tmr2;
  tmr2.start(10.0);
  tmr.start(0.1);
  alt {
    [] tmr2.timeout { setverdict(fail, "Default altstep not called."); }
  }
  finally_counter := cvar;
  if (finally_counter != 6) {
    setverdict(fail, "Invalid 'finally' execution count: ", finally_counter);
  }
}


testcase tc_exceptions_testcase() runs on CT {
  raise 100;
  cvar := -1;
}
catch (integer x) {
  cvar := x;
}
finally {
  if (cvar == 100) {
    setverdict(pass);
  }
  else if (cvar == 4) {
    setverdict(fail, "Exception not caught.");
  }
  else if (cvar == -1) {
    setverdict(fail, "Not exception raised.");
  }
  else {
    setverdict(fail, "Unknown error...");
  }
}
  

control {
  execute(tc_exceptions_block());
  execute(tc_exceptions_function());
  execute(tc_exceptions_altstep());
  execute(tc_exceptions_testcase());
}

}