# SPDX-FileCopyrightText: Huawei Inc.
#
# SPDX-License-Identifier: Apache-2.0

DISTRO = "oniro-linux"
DISTRO_NAME = "Oniro Project Base Linux Distro"
DISTRO_VERSION = "1.0.0-beta"
DISTRO_CODENAME = "dunfell"
SDK_VENDOR = "-onirosdk"
SDK_VERSION = "${@d.getVar('DISTRO_VERSION').replace('snapshot-${DATE}', 'snapshot')}"

MAINTAINER = "Oniro Project <andrei.gherzan@huawei.com>"

TARGET_VENDOR = "-oniro"

LOCALCONF_VERSION = "1"

DISTRO_VERSION[vardepsexclude] = "DATE"
SDK_VERSION[vardepsexclude] = "DATE"

# Override these in oniro based distros
ONIRO_DEFAULT_DISTRO_FEATURES = "largefile opengl ptest multiarch wayland vulkan"
ONIRO_DEFAULT_EXTRA_RDEPENDS = "packagegroup-core-boot"
ONIRO_DEFAULT_EXTRA_RRECOMMENDS = "kernel-module-af-packet"

DISTRO_FEATURES ?= "${DISTRO_FEATURES_DEFAULT} ${ONIRO_DEFAULT_DISTRO_FEATURES}"

PREFERRED_VERSION_linux-yocto ?= "5.4%"

SDK_NAME = "${DISTRO}-${TCLIBC}-${SDKMACHINE}-${IMAGE_BASENAME}-${TUNE_PKGARCH}-${MACHINE}"
SDKPATHINSTALL = "/opt/${DISTRO}/${SDK_VERSION}"

DISTRO_EXTRA_RDEPENDS += " ${ONIRO_DEFAULT_EXTRA_RDEPENDS}"
DISTRO_EXTRA_RRECOMMENDS += " ${ONIRO_DEFAULT_EXTRA_RRECOMMENDS}"

ONIROQEMUDEPS = "${@bb.utils.contains("INCOMPATIBLE_LICENSE", "GPL-3.0", "", "packagegroup-core-device-devel",d)}"
DISTRO_EXTRA_RDEPENDS_append_qemuarm = " ${ONIROQEMUDEPS}"
DISTRO_EXTRA_RDEPENDS_append_qemuarm64 = " ${ONIROQEMUDEPS}"
DISTRO_EXTRA_RDEPENDS_append_qemumips = " ${ONIROQEMUDEPS}"
DISTRO_EXTRA_RDEPENDS_append_qemuppc = " ${ONIROQEMUDEPS}"
DISTRO_EXTRA_RDEPENDS_append_qemux86 = " ${ONIROQEMUDEPS}"
DISTRO_EXTRA_RDEPENDS_append_qemux86-64 = " ${ONIROQEMUDEPS}"

TCLIBCAPPEND = ""

PREMIRRORS ??= "\
bzr://.*/.*   http://downloads.yoctoproject.org/mirror/sources/ \n \
cvs://.*/.*   http://downloads.yoctoproject.org/mirror/sources/ \n \
git://.*/.*   http://downloads.yoctoproject.org/mirror/sources/ \n \
gitsm://.*/.* http://downloads.yoctoproject.org/mirror/sources/ \n \
hg://.*/.*    http://downloads.yoctoproject.org/mirror/sources/ \n \
osc://.*/.*   http://downloads.yoctoproject.org/mirror/sources/ \n \
p4://.*/.*    http://downloads.yoctoproject.org/mirror/sources/ \n \
svn://.*/.*   http://downloads.yoctoproject.org/mirror/sources/ \n"

SANITY_TESTED_DISTROS ?= " \
            ubuntu-16.04 \n \
            ubuntu-18.04 \n \
            ubuntu-19.04 \n \
            ubuntu-20.04 \n \
            fedora-30 \n \
            fedora-31 \n \
            fedora-32 \n \
            fedora-33 \n \
            centos-7 \n \
            centos-8 \n \
            debian-8 \n \
            debian-9 \n \
            debian-10 \n \
            opensuseleap-15.1 \n \
            opensuseleap-15.2 \n \
            "

# QA check settings - a little stricter than the OE-Core defaults
WARN_TO_ERROR_QA = "already-stripped compile-host-path install-host-path \
                    installed-vs-shipped ldflags pn-overrides rpaths staticdev \
                    unknown-configure-option useless-rpaths"
WARN_QA_remove = "${WARN_TO_ERROR_QA}"
ERROR_QA_append = " ${WARN_TO_ERROR_QA}"

require conf/distro/include/no-static-libs.inc
require conf/distro/include/yocto-uninative.inc
require conf/distro/include/security_flags.inc
INHERIT += "uninative"

INHERIT += "reproducible_build"

BB_SIGNATURE_HANDLER ?= "OEEquivHash"
BB_HASHSERVE ??= "auto"

require conf/distro/include/oniro.inc
require conf/distro/include/oniro-wic.inc

TCLIBC ?= "musl"

BINUVERSION ?= "2.37%"
GCCVERSION ?= "11.%"
GLIBCVERSION ?= "2.33%"

INIT_MANAGER = "systemd"

# Remove some of the default Poky DISTRO_FEATURES we inherited, but do not use.
DISTRO_FEATURES_remove = " nfs nfc 3g pcmcia"

# Remove some of the default Poky IMAGE_FEATURES we inherited, but do not need.
IMAGE_FEATURES_remove = " nfs-server nfs-client nfs-utils"

# Remove some of the default Poky runtime dependencies that have no use
DISTRO_EXTRA_RDEPENDS_remove = " packagegroup-core-device-devel"

PREFERRED_VERSION_linux-raspberrypi = "5.10.%"
PREFERRED_VERSION_linux-yocto = "5.10%"
PREFERRED_PROVIDER_virtual/kernel_qemuarm = "linux-oniro"
PREFERRED_PROVIDER_virtual/kernel_qemuarm64 = "linux-oniro"
PREFERRED_PROVIDER_virtual/kernel_qemux86 = "linux-oniro"
PREFERRED_PROVIDER_virtual/kernel_qemux86-64 = "linux-oniro"

# Default to enabling serial debug console on RaspberryPi
ENABLE_UART ?= "1"

# We have no use for dlt-daemon as we use systemd for logging
PACKAGECONFIG_remove_pn-mosquitto = "dlt"

# We use NetworkManager as the default network manager (included in our
# reference images).
PACKAGECONFIG_remove_pn-systemd = "networkd"